初代MSXとアスキースティックの組み合わせ。初めてのパソコンとして、ゲーム機として、そしてパソコン通信やマルチメディアのためのホビー機として、MSXは支持された
現在30代以上で、その昔パソコン少年だった読者なら、MSXという言葉に反応するかもしれない。
「MSX」とは、1983年にアスキー（現在のアスキー・メディアワークス）とマイクロソフトによって提唱された、8bitパソコンの世界統一規格。日本ではソニー・松下電器産業（現在のパナソニック）・東芝・富士通といった現在でもPCを発売しているメーカーのほか、日立製作所や三洋電機・ビクター・カシオなど家電のメーカーもMSXに参入していたのだ。
ちなみに1983年は、任天堂からファミコン（ファミリーコンピュータ）が発売された年でもある。ほぼゲーム専用機だったファミコンに対して、MSXはれっきとしたパソコンであり、自分でプログラムを組んで楽しむこともできた。その影響力は、現在のIT業界で活躍するプログラマーの多くが「自分はMSXで育った」とコメントするほどである。
あの「MSX」がWindows Mobileでよみがえる！
そんなMSXが、およそ25年の時を経て現代のマシンによみがえる。Windows Mobile機向けのエミュレーターソフトをインストールすることで、スマートフォン上で往年のMSXの環境を再現できるのだ。
イー・モバイルのEM・ONEαを買うと、MSX MAGAZINE限定版が付いてくるキャンペーンが現在実施中だ
(c)1984 iTAChoco Systems Original created by iTAChoco=Rasho ENTERBRAIN, INC.
アスキー・メディアワークスでは昨年から1000台の台数限定で、イーモバイルの「EM・ONEα」に、エミュレーターソフトと「ボコスカウォーズ」を始めとした市販ソフト10本をセットにしたCD-ROMを添付したパッケージを販売している（関連サイト）。イー・モバイルから発売されている「EM・ONEα」は、大きなサイズの液晶画面にフルキーボードを搭載し、まさにゲームだけでなくプログラムも可能なMSXにとってふさわしい環境と言えるだろう。
「EM・ONEα」の中にMSXを再現させるのは「MSXPLAYer」というソフトウェアだ。これをインストールすることで、君の端末の中にMSXが組み込まれる。当然持ち運びだってできるのだ。MSXPLAYerには多くのゲームソフトが同梱されている。これらはかつて実際に市販されていたり、雑誌に投稿されたプログラムなのだ。
当然ながら現代のゲームと比べればとてもシンプルな内容だが、小さい中にもゲーム本来の楽しさが詰まっている。また、プログラミングによってこういったゲームを自作できる。作ったソフトをポケットに忍ばせて友達に見せられる点はとても嬉しい。
「EM・ONEα」×「MSX MAGAZINE」スペシャルコラボ展開中
MSXのゲームやゲームの自作ができるMSX BASICが収録された「EM-ONEα」の同梱版も限定発売中だ
また、MSXゲーム10本とゲームを自作できる「MSX BASIC」を収録した「MSX MAGAZINE特別号 CD-ROM版」の付いた「EM・ONEα」が販売されている。ここでしか買えない限定1000台のスペシャルパッケージだ。
■関連サイト
「EM・ONEα」「MSX MAGAZINE」スペシャルコラボキャンペーンBASIC言語でプログラムを動かそう！
MSXPLAYerはMSXそのものだから当然プログラミング環境も入っている。モバイル機器の中でプログラムが作れるというのは、実はけっこう画期的なことなのだ。
MSXのプログラミング言語は「MSX-BASIC」だ。Windowsの開発環境である「Visual Basic」を知っている人も多いだろうが、Visual BasicのルーツもBASICである。文法的にも共通点が多く、BASICを知ることは、これからプログラムを学びたい人にとっても役立つはずだ。
【モード選択画面】最初に1か2を入力してEnterキーを押す。1はふつうのゲームモードだが、2は画面が表示されないので覚えるのがすごく難しいぞ
G2 Co.,LTD
【出題画面】「LISTEN」と表示されたら音の出題が始まる。音にあわせてカーソルキーの各方向に対応したトランプのマークが点滅する
G2 Co.,LTD
【解答画面】「ANSWER」と表示されたら解答に移る。覚えた通りにカーソルキーを押して、同じ音を再現しよう
G2 Co.,LTD
【GAME OVER】途中で間違えてしまったらゲームオーバーだ。このときSpaceキーを押すことでプログラムは終了する
G2 Co.,LTD
ここでは、簡単なサンプルプログラムを用意した。記憶力が試される「音あてゲーム」だ。ルールは単純。カーソルキーにそれぞれ音が割り当てられているので、鳴った音をそのまま順番通りに再現していけばよい。正解するごとに覚える音がひとつずつ増えていき、10個覚えることができればクリアとなる。途中でひとつでも間違えてしまうと、残念ながらゲームオーバーだ。
■サンプルプログラム「音あてゲーム」
10 'oto ate game
20 'init
30 SCREEN 1:COLOR 1,15,15:DEFINT A-Z
40 DEFINT A-Z:DEFUSR=&H156
50 'select type
60 PRINT "1 か゛めんひょうし゛あり":PRINT "2 おと のみ"
70 A=USR(0):INPUT "と゛ちらにしますか";ED
80 SCREEN 3:OPEN "GRP:" FOR OUTPUT AS #1
90 FOR N=1 TO 4:C=0:GOSUB 450:NEXT
100 PLAY"V15L4"
110 'make question
120 DIM Q(30):A=RND(-TIME)
130 FOR I=0 TO 30:Q(I)=RND(1)*4+1:NEXT:SM=0
140 'play&display question
150 LINE(0,0)-STEP(63*4,7*4),15,BF
160 PSET(8*4,0),0:COLOR 4:PRINT #1,"LISTEN"
170 FOR ST=0 TO SM:N=Q(ST)
180 GOSUB 390:IF ED=1 THEN C=15:GOSUB 450:C=0:GOSUB 450
190 IF PLAY(0) THEN 190
200 NEXT ST
210 'answer
220 LINE(0,0)-STEP(63*4,7*4),15,BF
230 PSET(8*4,0),0:COLOR 8:PRINT #1,"ANSWER"
240 FOR ST=0 TO SM
250 IF STICK(0) GOTO 250
260 N=(STICK(0)+1)\2:IF N=0 GOTO 260
270 GOSUB 390:IF ED=1 THEN C=15:GOSUB 450:C=0:GOSUB 450
280 IF Q(ST)<>N THEN ST=SM:NEXT:GOTO 520
290 NEXT ST
300 'next step
310 IF PLAY(0) GOTO 310
320 SM=SM+1:IF SM<10 GOTO 150
330 'all clear
340 CLS
350 PSET(8*4,20*4),0:COLOR 1:PRINT #1,"CLEAR!"
360 IF STICK(0)=0 AND STRIG(0)=0 GOTO 360
370 END
380 'play
390 ON N GOTO 400,410,420,430
400 PLAY"O4C":RETURN
410 PLAY"O4E":RETURN
420 PLAY"O4G":RETURN
430 PLAY"O5C":RETURN
440 'draw
450 IF C THEN COLOR C ELSE COLOR 2^(N-1)
460 ON N GOTO 470,480,490,500
470 PSET(24*4,12*4),0:PRINT #1,CHR$(128)+"C":RETURN
480 PSET(36*4,20*4),0:PRINT #1,CHR$(130)+"E":RETURN
490 PSET(24*4,28*4),0:PRINT #1,CHR$(131)+"G":RETURN
500 PSET(12*4,20*4),0:PRINT #1,CHR$(129)+"c":RETURN
510 'out!
520 IF PLAY(0) GOTO 520
530 CLS
540 PSET(8*4,16*4),0:COLOR 1:PRINT #1,"MISS!"
550 PSET(0*4,24*4),0:COLOR 1:PRINT #1,"GAMEOVER"
560 IF (STICK(0)-STRIG(0))=0 GOTO 360
570 END
「EM・ONEα」を入手したら、ぜひこのプログラムを自分で入力してみてほしい。MSXPLAYerの詳しい操作方法は、同梱のCD-ROM『MSXマガジン特別号 EM・ONEα 遊べる！作れる！ゲーム＆BASIC』の中で紹介しているぞ。この短いプログラムの中でゲームがきちんと成立していることに驚くはずだ。
ひと通りゲームで遊んだら、今度は自分の手で改造してみるとよいだろう。例えば、行番号320に書かれている「SM＜10」の10を書き換えると、クリアするために覚える必要がある数を変更することができる。他にも音の種類を増やしてみたり、実際の曲を演奏させてみたり…すべてはキミのアイデアしだいだ。
BASICにひと通り慣れたら、今度はオリジナルのゲーム作りにもチャレンジしてみよう。自分で作ったゲームを友だちに見せびらかしたり、２人で遊べるゲームを作って対戦したりすれば、楽しみながらプログラムの腕も身につくに違いない。
ゲームで遊ぶもよし。自分でゲームを作るもよし。「EM・ONEα」をゲットして、気軽にMSXの世界を楽しもう！
